***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Sep 12, 2019                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt   PJD85N03-AU   D   G   S
*****param & model definition***
.model  dmos  nmos(
+    l = 1e-6		  w = 1e-6			level = 3
+ kappa = 5e-2
+  vto = 1.95		 kp = 107.3)
.model  dds   d(
+   is = 1.524e-11	  n = 1.027			   rs = 2.551e-3
+   eg = 1.087		trs1 = 3.000e-2)
.model  dbody d(
+   is = 1.524e-11	  n = 1.027			   rs = 2.551e-3
+  cjo = 7.519e-10	  m = 4.461e-1		   vj = 3.385e-1
+   bv = 33			ibv = 250e-6		 tbv1 = 9.384e-4			 tt = 25n)
.model  inter  nmos(
+  vto = 0			 kp = 10			level = 1)
.model  dgd    d(
+  cjo = 1.020e-9		  m = 4.295e-1		   vj = 5.474e-1)
.param
+  cgs = 3.378e-9		cgd = 9.397e-10
+   rd = 3.928e-4		 ra = 3.928e-4		 trd1 = 3.054e-2			trd2 = -6.578e-5
*****function & circuit***
rg	  G  1t   1
cgs	 1t   3   {cgs}   ic = 0
egv	  2t  3   table   {v(1t, S)} 
+((0   , 0   ),
+ (1   , 1   ), 
+ (2   , 2   ),
+ (2.5 , 2.5 ),
+ (3   , 3   ),
+ (4   , 4.1 ),
+ (4.25, 4.32),
+ (4.5 , 4.5 ),
+ (5   , 4.85),
+ (6   , 5.25),
+ (8   , 5.82),
+ (10  , 6.28),   
+ (20  , 6.5 ),
+ (22  , 6.5 ))
egt	  1  2t   value = {1.087e-3*limit(v(2t,3),0,1.8)*limit((temp-25),-80,125)}
mmain	  2   1   3   3   dmos
rd	  D   4   {rd}    tc = {trd1}
dds	  3   4   dds
dbody	  3   D   dbody
ra	  4   2   {ra} 
rs	  3   5   1e-4
ls	  5   S   0.001n 
m1     1t   8   6   6   inter
e1      8   6   4   1t  2
cgd	  7   4   {cgd}   ic = 0
rcgd    7   4   10meg
dgd     6   4   dgd
rdgd    4   6   10meg
m2      7   9  1t  1t   inter
e2      9  1t   4  1t   -2
.ends 
*$
